Landau-Lifschitz, Synge, and Fock pseudotensors compared

Lyudmil Antonov

lantonov.here@gmail.com

In a previous post, I showed a detailed derivation of the Landau-Lifshitz pseudotensor in all its forms: metric (canonical), Christoffel, and metric densities. Here, I'll widen the scope of analysis by clarifying why the metric density form is preferred in the literature, and also derive the closely related Synge and Fock pseudotensors and compare them to the Landau-Lifshitz pseudotensor.

Synge's stress-energy (pseudo)tensor of the gravitational field

Next, I will show an original way to obtain a stress-energy pseudotensor that belongs to John Lighton Synge in his book [2]. Synge's approach is entirely based at the level of Christoffels and higher levels not bothering to go down to metrics.

Synge defines Ricci tensor in somewhat different manner that LL. The Book simplifies the Riemann tensor by the first and third indices while Synge simplifies by the second and fourth indices. The latter definition differs by sign from LL as mentioned in the Book (footnote to formula LL92.6) and in Singe (footnote to formula I-(104)). Here, we will recheck Synge's proof, using the Ricci tensor as defined in Synge. Let's define Riemann by Christoffels as in LL91,4:

RiemannLL = MakeRule[{RiemannCD[i, -k, -l, -m], PD[-l][ChristoffelCD[i, -k, -m]] - PD[-m][ChristoffelCD[i, -k, -l]] + ChristoffelCD[i, -n, -l] ChristoffelCD[n, -k, -m] - ChristoffelCD[i, -n, -m] ChristoffelCD[n, -k, -l]}]; (*LL91,4*)
Equal[RiemannCD[i, -k, -l, -m], RiemannCD[i, -k, -l, -m] /. RiemannLL]

$$R^{i}_{klm} = \Gamma^{i}_{km,l} - \Gamma^{i}_{kl,m} - \Gamma^{i}_{nm} \Gamma^{n}_{kl} + \Gamma^{i}_{nl} \Gamma^{n}_{km}$$

We transfer the terms containing the second derivatives on the LHS and the Riemann tensor on the RHS

Equal[%[[2, 3]] + %[[2, 4]], -%[[2, 1]] - %[[2, 2]] + %[[1]]]

$$\Gamma^{i}_{km,l} -\Gamma^{i}_{kl,m} = R^{i}_{klm} - \Gamma^{i}_{nl} \Gamma^{n}_{km} + \Gamma^{i}_{nm} \Gamma^{n}_{kl}$$

For the Ricci tensor we make a rule exactly as in LL92,7

RicciLL = MakeRule[{RicciCD[-i, -k], PD[-l][ChristoffelCD[l, -i, -k]] - PD[-k][ChristoffelCD[l, -i, -l]] + ChristoffelCD[l, -i, -k] ChristoffelCD[m, -l, -m] - ChristoffelCD[m, -i, -l] ChristoffelCD[l, -k, -m]}]; (*LL92,7*)
Equal[RicciCD[-i, -k], RicciCD[-i, -k] /. RicciLL];
Equal[%[[2, 3]] + %[[2, 4]], -%[[2, 1]] - %[[2, 2]] + %[[1]]]

$$\Gamma^{l}_{ik,l} - \Gamma^{l}_{il,k} = R_{ik} -\Gamma^{l}_{ik} \Gamma^{m}_{lm} + \Gamma^{l}_{km} \Gamma^{m}_{il}$$

Compare these with the Synge's formulae VI-(151) on page 254:

$\Gamma^{i}_{kl,m} -\Gamma^{i}_{km,l} = R^{i}_{kml} - \Gamma^{i}_{nm} \Gamma^{n}_{kl} + \Gamma^{i}_{nl} \Gamma^{n}_{km}$
$\Gamma^{l}_{lk,i} - \Gamma^{l}_{ik,l} = R_{ik} -\Gamma^{l}_{im} \Gamma^{m}_{kl} + \Gamma^{l}_{ik} \Gamma^{m}_{lm}$

It is easy to see several differences in indices, some of which are sign changes, and others are due to reshuffling of the antisymmetric indices l and m which amounts to the same.

Let's reiterate the formula for $T^{ik}$ given above and look at it from somewhat different angle

$(-g)T^{ik} = \frac{c^4}{16 \pi k} \left[(-g) \left( g^{ik} g^{lm} - g^{il} g^{km} \right) \right]_{,m,l}$

The expression in the brackets can be replaced with a tensor

$U^{iklm} = (-g) \left( g^{ik} g^{lm} -g^{il} g^{km} \right)$

The order of indexes in $U^{iklm}$ is not arbitrary but so chosen that $U^{iklm}$ has the same symmetries as the Riemann tensor $R^{iklm}$ namely antisymmetric for each index pairs ik and lm and symmetric for permutation of these pairs.

DefTensor[U[i, k, l, m], M4, RiemannSymmetric[{1, 2, 3, 4}]];
U1 = MakeRule[{U[i, k, l, m], Detmetricg[] (metricg[i, k] metricg[l, m] - metricg[i, l] metricg[k,m])}];

** DefTensor: Defining tensor U[i,k,l,m].

$U^{iklm}$ corresponds to $\lambda^{iklm}$ from LL96,3 but without the constant $\frac{c^4}{16 \pi k}$

Next, Synge observes that if $U^{iklm}$ has the same symmetries as the Riemann tensor $R^{iklm}$ then its third derivatives by lmk should be zero. Let's check

ToCanonical[PD[-k][PD[-l][PD[-m][U[i, l, k, m]/.U1]]]] == 0

true

and the covariant derivative of $U^{iklm}$ vanish as well

ToCanonical[CD[-n][U[i, k, l, m]./U1]] == 0

true

Let's develop the CD by an arbitrary index n to Christoffels as is its usual definition, not forgetting that this whole expression is zero. We will put the metric determinant on hold so that the expression will not be processed so as to nullify the covariant derivative of the determinant

SetOptions[ToCanonical, UseMetricOnVBundle -> None];
CDbyN = CD[-n][1/Hold[Detmetricg[]] U[i, k, l, m]] // CovDToChristoffel

$$-\frac{U^{iklm} g_{,n}}{g^2} + \frac{\Gamma^{m}_{ns} U^{ikls} + \Gamma^{l}_{nr} U^{ikrm} + \Gamma^{k}_{nq} U^{iqlm} + \Gamma^{i}_{np} U^{pklm} + U^{iklm}_{,n}}{g}$$

Since the LHS is zero, we can multiply this expression by g to get rid of the denominator

Uiklmn = Hold[Detmetricg[]] CDbyN // Expand

$$\Gamma^{m}_{np} U^{iklp} + \Gamma^{l}_{np}U^{ikpm} + \Gamma^{k}_{np}U^{iplm} + \Gamma^{i}_{np} U^{pklm} - \frac{U^{iklm}g_{,n}}{g} + U^{iklm}_{,n}$$

According to LL86,5 $\frac{g_{,n}}{g} = 2\Gamma^p_{np}$ and substituting it and transferring $U^{iklm}_{,n}$ on the other side of the equation, we obtain Synge's VI-(153)

Uiklmn /. {PD[-n][Hold[Detmetricg[]]]/Hold[Detmetricg[]] -> 2 ChristoffelCD[p, -n, -p]}

$$-2\Gamma^{p}_{np} U^{iklm} + \Gamma^{m}_{np} U^{iklp} + \Gamma^{l}_{np} U^{ikpm} + \Gamma^{k}_{np} U^{iplm} + \Gamma^{i}_{np} U^{pklm} + U^{iklm}_{,n}$$

Uiklmn = -(%[[1]] + %[[2]] + %[[3]] + %[[4]] + %[[5]])

$$2\Gamma^p_{np}U^{iklm} - \Gamma^{m}_{np} U^{iklp} - \Gamma^{l}_{np}U^{ikpm} - \Gamma^{k}_{np}U^{iplm} - \Gamma^{i}_{np} U^{pklm}$$

To get the covariant derivative by k, simply substitute n by k

Uiklmn /. {n -> k}
Uiklmk = %/.{p -> n}

$$2\Gamma^n_{kn}U^{iklm} - \Gamma^{m}_{kn} U^{ikln} - \Gamma^{l}_{kn}U^{iknm} - \Gamma^{k}_{kn}U^{inlm} - \Gamma^{i}_{kn} U^{nklm}$$

Canonicalization reduces the terms from 5 to 3

UiklmkCan = Uiklmk // ToCanonical

$$-\Gamma^{m}_{kn} U^{ikln} + \Gamma^{l}_{kn} U^{ikmn} + \Gamma^{k}_{kn} U^{inlm}$$

Since canonicalization is not transparent, let me explain what is going on. In the fourth term, we exchange the dummy indices k and n. This does not change sign because k and n are symmetric in $\Gamma^{k}_{kn}$.

$\Gamma^{k}_{kn}U^{inlm} = \Gamma^{n}_{nk}U^{iklm} = \Gamma^{n}_{kn}U^{iklm}$

Then the fourth term cancels with the first term to give $\Gamma^n_{kn}U^{iklm}$. In the last term, we see that k and n are symmetric in $\Gamma^{i}_{kn}$ but antisymmetric in $U^{nklm}$. So, if we symmetrize the last term by n and k

Symmetrize[ChristoffelCD[i, -k, -n] U[n, k, l, m], {n, k}]

$$\frac{1}{2} \left(\Gamma^{i}_{kn} U^{knlm} + \Gamma^{i}_{kn} U^{nklm} \right)$$

But $U^{nklm} = -U^{knlm}$ and the above expression becomes zero

ToCanonical[Symmetrize[ChristoffelCD[i, -k, -n] U[n, k, l, m], {n, k}]] == 0

true

It remains to do some cosmetic changes to the canonicalized Uiklmk: exchange k and n in the last term which does not change sign

$\Gamma^{k}_{kn} U^{inlm} = \Gamma^{n}_{nk} U^{iklm} = \Gamma^{n}_{kn} U^{iklm}$

and exchange m and n in the second term, which changes sign

$\Gamma^{l}_{kn} U^{ikmn} = -\Gamma^{l}_{kn} U^{iknm}$

The expression for Uiklmk becomes

$\Gamma^{n}_{kn} U^{iklm} - \Gamma^{l}_{kn} U^{iknm} - \Gamma^{m}_{kn} U^{ikln}$

the same as Singe's VI-(154).

An ordinary differentiation of the above by m gives

Uiklmkm = PD[-m][UiklmkCan]

$$U^{inlm} \Gamma^{k}_{kn,m} - U^{ikmn} \Gamma^{l}_{kn,m} - U^{ikln} \Gamma^{m}_{kn,m} - \Gamma^{m}_{kn} U^{ikln}_{,m} - \Gamma^{l}_{kn} U^{ikmn}_{,m} + \Gamma^{k}_{kn} U^{inlm}_{,m}$$

Note that the second derivatives of the metric are contained in the first three terms, while terms 4,5,6 contain only first derivatives. We will separate second and first derivatives in the tensors Ail and Bil, respectively. As we will not use Ail and Bil for tensor operations, it suffice to treat them just as ordinary variables. We will also do a simplification of Ail, which factors common multipliers

Ail = Uiklmkm[[1 ;; 3]] // Simplification
Bil = Uiklmkm[[4 ;; 6]]

$$U^{imln} \left( -\Gamma^k_{mn,k} + \Gamma^k_{km,n} \right) - U^{ikmn}\Gamma^l_{km,n}$$ $$-\Gamma^m_{kn}U^{ikln}_{,m} + \Gamma^l_{kn}U^{ikmn}_{,m} + \Gamma^k_{kn}U^{inlm}_{,m}$$

Here, Synge's idea is to substitute the expression in parentheses in Ail, containing second metric derivatives with the RHS of the equation containing the Ricci tensor plus first metric derivatives. Let's exchange the dummy indices: $k \rightarrow m \rightarrow n$:

$U^{imln} \left( -\Gamma^k_{mn,k} + \Gamma^k_{km,n} \right) = U^{ikln} \left( -\Gamma^m_{kn,m} + \Gamma^m_{km,n} \right) = U^{iklm} \left( \Gamma^n_{kn,m} - \Gamma^n_{km,n} \right)$

The third term in Ail is transformed in

$-U^{ikmn}\Gamma^l_{km,n} = U^{iknm}\Gamma^l_{kn,m}$

and antisymmetrized by the lower n and m

Antisymmetrize[ U[i, k, n, m] PD[-n][ChristoffelCD[l, -k, -m]], {-n, -m}]

$$\frac{1}{2} U^{iknm} \left( \Gamma^l_{km,n} - \Gamma^l_{kn,m} \right)$$

Thus, for Ail we arrive to Singe's VI-(157)

$A^{il} = U^{iklm} \left( \Gamma^n_{kn,m} - \Gamma^n_{km,n} \right) + \frac{1}{2} U^{iknm} \left( \Gamma^l_{km,n} - \Gamma^l_{kn,m} \right)$

Now substitute the terms in the first parentheses with the RHS of the expression for the Ricci tensor as defined by Synge:

$U^{iklm} \left( \Gamma^n_{kn,m} - \Gamma^n_{km,n} \right) = U^{iklm} R_{km} + U^{iklm} \left( \Gamma^{n}_{km} \Gamma^{p}_{np} - \Gamma^{n}_{mp} \Gamma^{p}_{kp} \right)$

The terms in the second parentheses are substituted with the RHS of the expression for the Riemann tensor as defined by Synge:

$\frac{1}{2} U^{iknm} \left( \Gamma^l_{km,n} - \Gamma^l_{kn,m} \right) = \frac{1}{2}U^{iknm}R^l_{knm} + \frac{1}{2}U^{iknm} \left( \Gamma^p_{kn} \Gamma^l_{mp} - \Gamma^p_{km} \Gamma^l_{np} \right)$

or, by changing the indices n and m in the second term

$\begin{multline} \frac{1}{2}U^{iknm} \left( \Gamma^p_{kn} \Gamma^l_{pm} - \Gamma^p_{km} \Gamma^l_{np} \right) = \frac{1}{2}U^{iknm}\Gamma^p_{kn} \Gamma^l_{pm} - \frac{1}{2}U^{iknm}\Gamma^p_{km} \Gamma^l_{np} = \\ \frac{1}{2}U^{iknm}\Gamma^p_{kn} \Gamma^l_{mp} + \frac{1}{2}U^{iknm}\Gamma^p_{kn} \Gamma^l_{mp} = U^{iknm}\Gamma^p_{kn} \Gamma^l_{mp} \end{multline}$

Substituting $U^{iklm}$ and $U^{iknm}$ with their equivalents in metric tensors and taking into account the sign difference of the Riemann tensor between Singe and the Book

U[i, k, l, m] RicciCD[-k, -m] /. U1 // ToCanonical // ContractMetric
- U[i, k, n, m] RiemannCD[l, -k, -n, -m] /. U1 // ToCanonical // ContractMetric

$$-g R^{il} + g g^{il} R$$ $$-g R^{il}$$

Summing these terms in Ail, we obtain

$A^{il} = -g \left( 2 R^{il} - g^{il} R \right) + U^{iklm} \left( \Gamma^{n}_{km} \Gamma^{p}_{np} - \Gamma^{n}_{mp} \Gamma^{p}_{kp} \right) + U^{iknm}\Gamma^p_{kn} \Gamma^l_{mp}$

$ -g \left( 2 R^{il} - g^{il} R \right) = - 2 g G^{il}$ where $G^{il}$ is the Einstein tensor

So, for $U^{iklm}_{,km}$ we have VI-(160)

$U^{iklm}_{,km} = - 2 g G^{il} + 2 V^{il}$

where $ 2 V^{il}$ is VI-(161)

$2 V^{il} = U^{iklm} \left( \Gamma^{n}_{km} \Gamma^{p}_{np} - \Gamma^{n}_{mp} \Gamma^{p}_{kp} \right) + U^{iknm}\Gamma^p_{kn} \Gamma^l_{mp} + B^{il}$

It remains to substitute Bil, expressed in terms of $U^{iklm}_n$ with the expression Synge VI-(153) obtained above. For this purpose we shall make a rule to be sure that the indices are handled properly.

rule1 = MakeRule[{PD[-n][U[i, k, l, m]], 2*ChristoffelCD[p, -n, -p]*U[i, k, l, m] - ChristoffelCD[m, -n, -p]*U[i, k, l, p] - ChristoffelCD[l, -n, -p]*U[i, k, p, m] - ChristoffelCD[k, -n, -p]*U[i, p, l, m] - ChristoffelCD[i, -n, -p]*U[p, k, l, m]}];
Bik /. rule1 // ToCanonical

$$\begin{multline} - \Gamma^{l}_{km} \Gamma^{n}_{np} U^{ikmp} + \Gamma^{k}_{km} \Gamma^{n}_{np} U^{imlp} + 2 \Gamma^{k}_{mn} \Gamma^{m}_{kp} U^{inlp} - 3 \Gamma^{k}_{km} \Gamma^{m}_{np} U^{inlp} + 2 \Gamma^{k}_{np} \Gamma^{l}_{km} U^{inmp} - \\ \Gamma^{i}_{km} \Gamma^{l}_{np} U^{knmp} - \Gamma^{i}_{km} \Gamma^{n}_{np} U^{lkmp} + \Gamma^{i}_{km} \Gamma^{k}_{np} U^{lnmp} \end{multline}$$

To these terms we should add the additional $U^{iklm}$ terms from I-(161)

% + U[i, k, l, m] (ChristoffelCD[n, -m, -k]*ChristoffelCD[p, -n, -p] - ChristoffelCD[n, -m, -p]*ChristoffelCD[p, -k, -n]) + U[i, k, n, m]*ChristoffelCD[p, -k, -n]*ChristoffelCD[l, -p, -m]
SyngeAutomatic = % // ToCanonical

$$\begin{multline} - \Gamma^{l}_{km} \Gamma^{n}_{np} U^{ikmp} + \Gamma^{k}_{km} \Gamma^{n}_{np} U^{imlp} + \Gamma^{k}_{mn} \Gamma^{m}_{kp} U^{inlp} - 2 \Gamma^{k}_{km} \Gamma^{m}_{np} U^{inlp} + \\ \Gamma^{k}_{np} \Gamma^{l}_{km} U^{inmp} - \Gamma^{i}_{km} \Gamma^{l}_{np} U^{knmp} - \Gamma^{i}_{km} \Gamma^{n}_{np} U^{lkmp} + \Gamma^{i}_{km} \Gamma^{k}_{np} U^{lnmp} \end{multline}$$

This is the Synge VI-(162) in an expanded form. We have to check it to be sure by manual entering and comparing.

U[i, k, l, m] (ChristoffelCD[n, -n, -k] ChristoffelCD[p, -p, -m] + ChristoffelCD[n, -p, -k] ChristoffelCD[p, -n, -m] - 2 ChristoffelCD[n, -k, -m] ChristoffelCD[p, -n, -p]) + U[i, k, m, n] (-ChristoffelCD[l, -k, -m] ChristoffelCD[p, -p, -n] - ChristoffelCD[p, -k, -m] ChristoffelCD[l, -p, -n]) + U[l, k, m, n] (-ChristoffelCD[i, -k, -m] ChristoffelCD[p, -p, -n] - ChristoffelCD[p, -k, -m] ChristoffelCD[i, -p, -n]) + U[k, m, n, p] ChristoffelCD[i, -k, -p] ChristoffelCD[l, -m, -n]
SyngeManual = % // ToCanonical

$$\begin{multline} - \Gamma^{l}_{km} \Gamma^{n}_{np} U^{ikmp} + \Gamma^{k}_{km} \Gamma^{n}_{np} U^{imlp} + \Gamma^{k}_{mn} \Gamma^{m}_{kp} U^{inlp} - 2 \Gamma^{k}_{km} \Gamma^{m}_{np} U^{inlp} + \\ \Gamma^{k}_{np} \Gamma^{l}_{km} U^{inmp} - \Gamma^{i}_{km} \Gamma^{l}_{np} U^{knmp} - \Gamma^{i}_{km} \Gamma^{n}_{np} U^{lkmp} + \Gamma^{i}_{km} \Gamma^{k}_{np} U^{lnmp} \end{multline}$$

SyngeAutomatic - SyngeManual == 0

true

The final result from our calculation is exactly the same as in Synge's book. Let's develop the $U^{iklm}$ terms to metrics to compare the Synge pseudotensor with the LL one.

SyngeAutomatic /. U1 // ToCanonical;
SyngeInMetrics = %/Detmetricg[] // ToCanonical

$$\begin{multline} \Gamma^{k}_{km} \Gamma^{n}_{np} g^{im} g^{lp} + \Gamma^{k}_{mn} \Gamma^{m}_{kp} g^{in} g^{lp} - 2 \Gamma^{k}_{km} \Gamma^{m}_{np} g^{in} g^{lp} - \Gamma^{k}_{km} \Gamma^{n}_{np} g^{il} g^{mp} + \Gamma^{k}_{np} \Gamma^{l}_{km} g^{in} g^{mp} - \\ \Gamma^{i}_{km} \Gamma^{l}_{np} g^{kn} g^{mp} + \Gamma^{i}_{km} \Gamma^{k}_{np} g^{ln} g^{mp} - \Gamma^{k}_{mn} \Gamma^{m}_{kp} g^{il} g^{np} + 2 \Gamma^{k}_{km} \Gamma^{m}_{np} g^{il} g^{np} - \Gamma^{k}_{np} \Gamma^{l}_{km} g^{im} g^{np} + \Gamma^{i}_{km} \Gamma^{l}_{np} g^{km} g^{np} - \Gamma^{i}_{km} \Gamma^{k}_{np} g^{lm} g^{np} \end{multline}$$

Not a good sign in terms of comparison. From 16 potential terms in Synge's pseudotensor, canonicalization leaves only 12. Canonicalization of the LL pseudotensor leaves all 16 terms. There is no point in futher direct comparison. Let's try to see where the difference lies. It was said above that Synge's $U^{iklm}$ is an analogue of the LL $\lambda^{iklm}$. In Synge, e.g. VI-(160), it is seen that the basis for the derivation is $U^{iklm}$ differentiated by its second and fourth indices, $U^{iklm}_{,k,m}$, leaving free the first and third indices. In LL, $\lambda^{iklm}$ is differentiated by the third and fourth indices, $\lambda^{iklm}_{,l,m}$, leaving free the first and second indices. See, e.g. LL96,2 and LL96,5. It's very possible this is the cause for the difference.

Let us try to derive the Synge's tensor with differentiations by the third and fourth indices.

Uiklmn /. {n -> l};
Uiklml = % /. {p -> n}

$$2 \Gamma^{n}_{ln} U^{iklm} - \Gamma^{m}_{ln} U^{ikln} - \Gamma^{l}{}_{ln} U^{iknm} - \Gamma^{k}_{ln} U^{inlm} - \Gamma^{i}_{ln} U^{nklm}$$

UiklmlCan = Uiklml // ToCanonical

$$- \Gamma^{l}_{ln} U^{ikmn} + \Gamma^{k}_{ln} U^{ilmn} - \Gamma^{i}_{ln} U^{klmn}$$

Uiklmlm = PD[-m][UiklmlCan]

$$- U^{klmn} \Gamma^{i}_{ln,m} + U^{ilmn} \Gamma^{k}_{ln,m} - U^{ikmn} \Gamma^{l}_{ln,m} - \Gamma^{l}_{ln} U^{ikmn}_{,m} + \Gamma^{k}_{ln} U^{ilmn}_{,m} - \Gamma^{i}_{ln} U^{klmn}_{,m}$$

Here, the terms with the second derivatives constituting the Aik tensor can no longer be arranged in Ricci tensor. This makes impossible to continue derivation of the Synge's pseudotensor.

As another check, let us see if the canonical pseudotensor derived from Synge's pseudotensor is the same as the LL canonical pseudotensor.

SyngeInMetrics/2 // ChristoffelToGradMetric // ToCanonical

$$\begin{multline} -\tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{nq}{}_{,k} g_{pr}{}_{,m} + \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{np}{}_{,k} g_{qr}{}_{,m} - \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{qr}{}_{,m} g_{kn}{}_{,p} - \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{qr}{}_{,k} g_{mn}{}_{,p} - \\ \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{mn}{}_{,k} g_{qr}{}_{,p} - \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{kn}{}_{,m} g_{qr}{}_{,p} - \tfrac{3}{8} g^{il} g^{km} g^{np} g^{qr} g_{km}{}_{,n} g_{qr}{}_{,p} + \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{km}{}_{,n} g_{qr}{}_{,p} + \\ \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{pr}{}_{,m} g_{kn}{}_{,q} - \tfrac{1}{4} g^{il} g^{km} g^{np} g^{qr} g_{mr}{}_{,p} g_{kn}{}_{,q} + \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{pr}{}_{,k} g_{mn}{}_{,q} + \tfrac{1}{8} g^{il} g^{km} g^{np} g^{qr} g_{kn}{}_{,q} g_{mp}{}_{,r} - \\ \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{kn}{}_{,q} g_{mp}{}_{,r} + \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{kn}{}_{,p} g_{mq}{}_{,r} + \tfrac{1}{2} g^{il} g^{km} g^{np} g^{qr} g_{km}{}_{,n} g_{pq}{}_{,r} - \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{km}{}_{,n} g_{pq}{}_{,r} \end{multline}$$

Surprise, the canonical Synge pseudotensor has 16 terms, the same as the canonical LL pseudotensor. Now if we immediately try to subtract the above from the canonical LL pseudotensor and canonicalize, we will be thrown an error in validation because of inhomogeneous indices. Indeed, the free indices of the above expression are i, l while in LL canonical they are i, k. Therefore, we must first make the free indices in the two expressions the same (i, k) and then compare by subtracting.

ChangeFreeIndices[%, {i, k}];
(LLCanonical - %) // ToCanonical

$$\begin{multline} \tfrac{1}{2} g^{il} g^{km} g^{np} g^{qr} g_{nq}{}_{,l} g_{pr}{}_{,m} - \tfrac{3}{4} g^{il} g^{km} g^{np} g^{qr} g_{np}{}_{,l} g_{qr}{}_{,m} + \tfrac{3}{4} g^{il} g^{km} g^{np} g^{qr} g_{qr}{}_{,m} g_{ln}{}_{,p} + \tfrac{3}{4} g^{il} g^{km} g^{np} g^{qr} g_{qr}{}_{,l} g_{mn}{}_{,p} + \\ \tfrac{1}{2} g^{il} g^{km} g^{np} g^{qr} g_{mn}{}_{,l} g_{qr}{}_{,p} + \tfrac{1}{2} g^{il} g^{km} g^{np} g^{qr} g_{ln}{}_{,m} g_{qr}{}_{,p} - \tfrac{5}{4} g^{il} g^{km} g^{np} g^{qr} g_{lm}{}_{,n} g_{qr}{}_{,p} + \tfrac{3}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{lm}{}_{,n} g_{qr}{}_{,p} - \\ g^{il} g^{km} g^{np} g^{qr} g_{pr}{}_{,m} g_{ln}{}_{,q} + \tfrac{1}{2} g^{ik} g^{lm} g^{np} g^{qr} g_{mr}{}_{,p} g_{ln}{}_{,q} - g^{il} g^{km} g^{np} g^{qr} g_{pr}{}_{,l} g_{mn}{}_{,q} + g^{il} g^{km} g^{np} g^{qr} g_{ln}{}_{,q} g_{mp}{}_{,r} - \\ \tfrac{1}{4} g^{ik} g^{lm} g^{np} g^{qr} g_{ln}{}_{,q} g_{mp}{}_{,r} - g^{il} g^{km} g^{np} g^{qr} g_{ln}{}_{,p} g_{mq}{}_{,r} + g^{il} g^{km} g^{np} g^{qr} g_{lm}{}_{,n} g_{pq}{}_{,r} - g^{ik} g^{lm} g^{np} g^{qr} g_{lm}{}_{,n} g_{pq}{}_{,r} \end{multline}$$

We see that subtracting the 2 pseudotensors tends to increase their numerical coefficients. This means that on the whole they are with somewhat opposite sign. So let's add them.

(LLCanonical + %) // ToCanonical

$$- \tfrac{1}{4} g^{il} g^{km} g^{np} g^{qr} g_{np}{}_{,l} g_{qr}{}_{,m} + \tfrac{1}{4} g^{il} g^{km} g^{np} g^{qr} g_{qr}{}_{,m} g_{ln}{}_{,p} + \tfrac{1}{4} g^{il} g^{km} g^{np} g^{qr} g_{qr}{}_{,l} g_{mn}{}_{,p} - \tfrac{1}{4} g^{il} g^{km} g^{np} g^{qr} g_{lm}{}_{,n} g_{qr}{}_{,p}$$

We can conclude from here that as whole the Synge pseudotensor is with a sign opposite to that of LL pseudotensor and the sum of the two pseudotensors leaves a small 4-terms residue.

Finally, let's see if the Synge pseudotensor is symmetric for the free indices i and l which is equivalent to antisymmetrizing it and equating it to 0.

ToCanonical[Antisymmetrize[SyngeAutomatic, {i, l}]] == 0

true

This shows that Synge's pseudotensor is symmetric.

Traffic Counter